'From Squeak5.3beta of 11 December 2019 [latest update: #19270] on 11 December 2019 at 11:57:25 am'!

!Context methodsFor: 'accessing' stamp: 'ct 12/11/2019 11:54'!
tempNamed: aString
	"Return the value of the temporary variable in me with that name. Slow (in O(n)), but very useful."

	^ self debuggerMap tempNamed: aString in: self! !

!Context methodsFor: 'accessing' stamp: 'ct 12/11/2019 11:55'!
tempNamed: aString put: aValue
	"Store into the value of the temporary variable in me of that name. Slow (in O(n)), but very useful."

	^ self debuggerMap
		tempNamed: aString
		put: aValue
		in: self! !


!DebuggerMethodMap methodsFor: 'accessing' stamp: 'ct 12/4/2019 13:00'!
tempIndexFor: tempName in: aContext ifAbsent: aBlock

	^ (self tempNamesForContext: aContext)
		indexOf: tempName
		ifAbsent: aBlock! !

!DebuggerMethodMap methodsFor: 'accessing' stamp: 'ct 12/11/2019 11:55'!
tempNamed: aString in: aContext
	"Return the value of the temporary variable in aContext with that name. Slow (in O(n)), but very useful."

	^ self
		namedTempAt: (self
			tempIndexFor: aString asString
			in: aContext
			ifAbsent: [self error: 'no such temp'])
		in: aContext! !

!DebuggerMethodMap methodsFor: 'accessing' stamp: 'ct 12/11/2019 11:55'!
tempNamed: aString put: aValue in: aContext
	"Store into the value of the temporary variable in aContext of that name. Slow (in O(n)), but very useful."

	^ self
		namedTempAt: (self
			tempIndexFor: aString asString
			in: aContext
			ifAbsent: [self error: 'no such temp'])
		put: aValue
		in: aContext! !


!DebuggerMethodMap reorganize!
('source mapping' abstractSourceMapForMethod: rangeForPC:in:contextIsActiveContext: sourceText)
('initialize-release' forMethod:methodNode:)
('accessing' markRecentlyUsed method namedTempAt:in: namedTempAt:put:in: tempIndexFor:in:ifAbsent: tempNamed:in: tempNamed:put:in: tempNamesForContext: tempsAndValuesForContext: timestamp)
('private' abstractSourceMap)
('*SBE-Extract-accessing')
!