[FIX] Three little fixes

Bert Freudenberg bert at isgnw.CS.Uni-Magdeburg.De
Fri Aug 20 15:06:19 UTC 1999


"Change Set:		threefixes-bf
Date:			20 August 1999
Author:			Bert Freudenberg

- Fixes FloatArray>>#= (exploring them blew up).
- Fixes MatrixTransform2x3>>#= (argument was misspelled).
- Reimplements String>>#includes: in terms of #indexOf: (great speedup by
  prim 245)"


  /bert

Content-Type: TEXT/PLAIN; charset=US-ASCII; name="threefixes-bf.20Aug405pm.cs"
Content-ID: <Pine.LNX.3.96.990820170619.11947B at balloon.cs.uni-magdeburg.de>
Content-Description: 

'From Squeak 2.5 of August 6, 1999 on 20 August 1999 at 4:05:10 pm'!
"Change Set:		threefixes-bf
Date:			20 August 1999
Author:			Bert Freudenberg

- Fixes FloatArray>>#= (exploring them blew up).
- Fixes MatrixTransform2x3>>#= (argument was misspelled).
- Reimplements String>>#includes: in terms of #indexOf: (great speedup by prim 245)"!


!FloatArray methodsFor: 'comparing' stamp: 'bf 8/20/1999 12:49'!
= aFloatArray 
	| length |
	<primitive: 'primitiveFloatArrayEqual'>
	aFloatArray class = self class ifFalse: [^ false].
	length _ self size.
	length = aFloatArray size ifFalse: [^ false].
	1 to: self size do: [:i | (self at: i)
			= (aFloatArray at: i) ifFalse: [^ false]].
	^ true! !


!MatrixTransform2x3 methodsFor: 'comparing' stamp: 'bf 8/20/1999 12:47'!
= aMatrixTransform2x3 
	| length |
	<primitive: 'primitiveFloatArrayEqual'>
	self class = aMatrixTransform2x3 class ifFalse: [^ false].
	length _ self size.
	length = aMatrixTransform2x3 size ifFalse: [^ false].
	1 to: self size do: [:i | (self at: i)
			= (aMatrixTransform2x3 at: i) ifFalse: [^ false]].
	^ true! !


!String methodsFor: 'testing' stamp: 'bf 8/20/1999 12:52'!
includes: aCharacter
	"Reimplemented for performance"
	^ (self indexOf: aCharacter) > 0! !





More information about the Squeak-dev mailing list