[BUG FIX] FileContentsBrowser class side ops
William O. Dargel
wDargel at shoshana.com
Thu Feb 4 02:11:47 UTC 1999
Attached are some fixes for the FileContentsBrowser. I thought that I
had submitted these changes before, but maybe they slipped though the
cracks.
-----------------
Fixes the FileContentsBrowser to work correctly on the Class side and
not just the Instance side.
- Class side message categories can now be filed in and filed out.
- The 'remove existing' menu selection on the message categories list
now works when the Class side is selected.
- And the 'remove existing' menu selection on the class list removes
both class and instance methods (just as fileOut or fileIn operate on
both the class and metaClass).
-------------------------------------------
Bill Dargel wdargel at shoshana.com
Shoshana Technologies
100 West Joy Road, Ann Arbor, MI 48105 USA
'From Squeak 2.3 of January 14, 1999 on 3 February 1999 at 7:15:19 pm'!
"Change Set: FileContentsBrowser Fixes
Date: 3 February 1999
Author: Bill Dargel wdargel at shoshana.com
Fixes the FileContentsBrowser to work correctly on the Class side and not just the Instance side.
Class side message categories can now be filed in and filed out.
The 'remove existing' menu selection on the message categories list now works when the Class side is selected.
And the 'remove existing' menu selection on the class list removes both class and instance methods (just as fileOut or fileIn operate on both the class and metaClass).
"!
!FileContentsBrowser methodsFor: 'removing' stamp: 'wod 2/3/1999 18:47'!
removeUnmodifiedCategories
| theClass |
self okToChange ifFalse: [^self].
theClass _ self selectedClass.
theClass isNil ifTrue: [^self].
Cursor wait showWhile:
[theClass removeUnmodifiedMethods: theClass selectors.
theClass metaClass removeUnmodifiedMethods: theClass metaClass selectors].
self messageCategoryListIndex: 0.
self changed: #messageCategoryList.! !
!FileContentsBrowser methodsFor: 'removing' stamp: 'wod 2/3/1999 18:47'!
removeUnmodifiedMethods
| theClass cat |
self okToChange ifFalse:[^self].
theClass := self selectedClassOrMetaClass.
theClass isNil ifTrue:[^self].
cat := self selectedMessageCategoryName.
cat isNil ifTrue:[^self].
Cursor wait showWhile:[
theClass removeUnmodifiedMethods: (theClass organization listAtCategoryNamed: cat).
].
self messageListIndex: 0.
self changed: #messageList.! !
!FileContentsBrowser methodsFor: 'fileIn/fileOut' stamp: 'wod 2/3/1999 18:46'!
fileInMessageCategories
Cursor read showWhile:[
self selectedClassOrMetaClass fileInCategory: self selectedMessageCategoryName.
].! !
!FileContentsBrowser methodsFor: 'fileIn/fileOut' stamp: 'wod 2/3/1999 18:46'!
fileOutMessageCategories
Cursor write showWhile:[
self selectedClassOrMetaClass fileOutCategory: self selectedMessageCategoryName.
].! !
More information about the Squeak-dev
mailing list
|