On 19/02/05 17:32, "Steven Swerling" <sswerling at yahoo.com> wrote:

> Steven Swerling wrote:
> Hopefully it gets put to shame quick. In the meantime, if something's
> missing, just put it back in, and if you'd be so kind, send me the patch.
> 
> 
Steven:

Here is the first fixes. (Now dual change sorter are working )

Image are 3.9 Mb now, but Sunit could be one addOn.

When I was kid , exist Meccano with all kinds of pieces for build thcutings.
And Meccano in Argentina have number as Meccano 1 was the smaller box and
Meccano 5 your build - dream.

So all this could end in a consensus of what size the smaller box is and
what nuts, bolts, etc must contain.

Always poor people of Argentina could cut a piece of wood or trying to
connect square pieces to round ones (But if you see Apollo 13 movie...)

Cheers

Edgar

-------------- next part --------------
'From Squeak3.7 of ''4 September 2004'' [latest update: #5989] on 20 February 2005 at 8:19:17 am'!
"Change Set:		QuiteSmallFixex
Date:			20 February 2005
Author:			Edgar J. De Cleene

I using all I lean about stripping here,
fixing what IMHO are missed in Pavel/Steven image"!


!ChangeSorter methodsFor: 'class list' stamp: 'nb 6/17/2003 12:25'!
copyClassToOther
	"Place these changes in the other changeSet also"

	| otherSorter otherChangeSet |
	self checkThatSidesDiffer: [^ self].
	self okToChange ifFalse: [^ Beeper beep].
	currentClassName ifNil: [^ Beeper beep].
	otherSorter _ parent other: self.
	otherChangeSet _ otherSorter changeSet.

	otherChangeSet absorbClass: self selectedClassOrMetaClass name from: myChangeSet.
	otherSorter showChangeSet: otherChangeSet.! !

!ChangeSorter methodsFor: 'class list' stamp: 'nb 6/17/2003 12:25'!
moveClassToOther
	"Place class changes in the other changeSet and remove them from this one"

	self checkThatSidesDiffer: [^ self].
	(self okToChange and: [currentClassName notNil]) ifFalse: [^ Beeper beep].

	self copyClassToOther.
	self forgetClass! !


!GradientFillStyle class methodsFor: 'as yet unclassified' stamp: 'edc 2/20/2005 06:01'!
sample
	"GradientFill sample"
	^(self ramp: { 0.0 -> Color red. 0.5 -> Color green. 1.0 -> Color blue})
		origin: 300 @ 300;
		direction: 400 at 0;
		normal: 0 at 400;
		radial: true;
	yourself! !


!Morph methodsFor: 'geometry' stamp: 'di 2/23/98 11:36'!
worldBounds
	^ self world bounds! !

!Morph methodsFor: 'layout-properties' stamp: 'edc 2/20/2005 05:53'!
vResizeToFit: aBoolean
	aBoolean ifTrue:[
		self vResizing: #shrinkWrap.
	] ifFalse:[
		self vResizing: #rigid.
	].! !


!AlignmentMorph class methodsFor: 'instance creation' stamp: 'dgd 9/20/2003 19:05'!
columnPrototype
	"Answer a prototypical column"

	| sampleMorphs aColumn |
	sampleMorphs _ #(red yellow green) collect:
		[:aColor | Morph new extent: 130 @ 38; color: (Color perform: aColor); setNameTo: aColor asString; yourself].
	aColumn _ self inAColumn: sampleMorphs.
	aColumn setNameTo: 'Column'.
	aColumn color: Color veryVeryLightGray.
	aColumn cellInset: 4; layoutInset: 6.
	aColumn enableDragNDrop.
	aColumn setBalloonText: 'Things dropped into here will automatically be organized into a column. Once you have added your own items here, you will want to remove the sample colored rectangles that this started with, and you will want to change this balloon help message to one of your own!!' translated.
	^ aColumn! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'sw 11/2/2001 04:45'!
inAColumn: aCollectionOfMorphs
	"Answer a columnar AlignmentMorph holding the given collection"

	| col |
	col _ self newColumn
		color: Color transparent;
		vResizing: #shrinkWrap;
		hResizing: #shrinkWrap;
		layoutInset: 1;
		borderColor: Color black;
		borderWidth: 1;
		wrapCentering: #center;
		cellPositioning: #topCenter.
	aCollectionOfMorphs do: [:each | col addMorphBack: each].
	^ col! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'sw 11/5/2001 15:11'!
inARow: aCollectionOfMorphs
	"Answer a row-oriented AlignmentMorph holding the given collection"

	| aRow |
	aRow _ self newRow
		color: Color transparent;
		vResizing: #shrinkWrap;
		hResizing: #shrinkWrap;
		layoutInset: 1;
		borderColor: Color black;
		borderWidth: 1;
		wrapCentering: #center;
		cellPositioning: #topCenter.
	aCollectionOfMorphs do: [ :each | aRow addMorphBack: each].
	^ aRow! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'ar 11/9/2000 20:51'!
newColumn

	^ self new
		listDirection: #topToBottom;
		hResizing: #spaceFill;
		extent: 1 at 1;
		vResizing: #spaceFill
! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'ar 11/9/2000 20:50'!
newRow

	^ self new
		listDirection: #leftToRight;
		hResizing: #spaceFill;
		vResizing: #spaceFill;
		extent: 1 at 1;
		borderWidth: 0
! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'ar 11/9/2000 20:37'!
newSpacer: aColor
	"Answer a space-filling instance of me of the given color."

	^ self new
		hResizing: #spaceFill;
		vResizing: #spaceFill;
		layoutInset: 0;
		borderWidth: 0;
		extent: 1 at 1;
		color: aColor.
! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'ar 11/9/2000 20:37'!
newVariableTransparentSpacer
	"Answer a space-filling instance of me of the given color."

	^ self new
		hResizing: #spaceFill;
		vResizing: #spaceFill;
		layoutInset: 0;
		borderWidth: 0;
		extent: 1 at 1;
		color: Color transparent
! !

!AlignmentMorph class methodsFor: 'instance creation' stamp: 'dgd 9/20/2003 19:05'!
rowPrototype
	"Answer a prototypical row"

	| sampleMorphs aRow |
	sampleMorphs _ (1 to: (2 + 3 atRandom)) collect:
		[:integer | EllipseMorph new extent: ((60 + (20 atRandom)) @ (80 + ((20 atRandom)))); color: Color random; setNameTo: ('egg',  integer asString); yourself].
	aRow _ self inARow: sampleMorphs.
	aRow setNameTo: 'Row'.
	aRow enableDragNDrop.
	aRow cellInset: 6.
	aRow layoutInset: 8.
	aRow setBalloonText: 'Things dropped into here will automatically be organized into a row. Once you have added your own items here, you will want to remove the sample colored eggs that this started with, and you will want to change this balloon help message to one of your own!!' translated.
	aRow color: Color veryVeryLightGray.
	^ aRow

			"AlignmentMorph rowPrototype openInHand"! !


!PasteUpMorph methodsFor: 'menu & halo' stamp: 'edc 2/20/2005 07:51'!
addCustomMenuItems: menu hand: aHandMorph
	"Add morph-specific menu itemns to the menu for the hand"

	super addCustomMenuItems: menu hand: aHandMorph.
	self addPenMenuItems: menu hand: aHandMorph.
	self addPlayfieldMenuItems: menu hand: aHandMorph.

	self isWorldMorph ifTrue:
		[
"Stubbed by Morphic Shrink"
		"(owner isKindOf: BOBTransformationMorph) ifTrue:
			[self addScalingMenuItems: menu hand: aHandMorph]."
		menu add: 'desktop menu...' translated target: self action: #putUpDesktopMenu:].

	menu addLine
! !

!PasteUpMorph methodsFor: 'options' stamp: 'edc 2/20/2005 05:55'!
autoLineLayout
	| layout |
	layout := self layoutPolicy ifNil:[^false].
	layout isTableLayout ifFalse:[^false].
	self listDirection == #leftToRight ifFalse:[^false].
	self wrapDirection == #topToBottom ifFalse:[^false].
	^true! !

!PasteUpMorph methodsFor: 'options' stamp: 'edc 2/20/2005 05:57'!
autoLineLayout: aBoolean
	"Make the receiver be viewed with auto-line-layout, which means that its submorphs will be laid out left-to-right and then top-to-bottom in the manner of a word processor, or (if aBoolean is false,) cease applying auto-line-layout"

	aBoolean ifTrue:
		[self viewingNormally ifTrue: [self saveBoundsOfSubmorphs]].
	aBoolean ifTrue:[
		self layoutPolicy: TableLayout new.
		self layoutInset: 8; cellInset: 4.
		self listDirection: #leftToRight; wrapDirection: #topToBottom.
	] ifFalse:[
		self layoutPolicy: nil.
		self layoutInset: 0; cellInset: 0.
	].
! !

!PasteUpMorph methodsFor: 'options' stamp: 'dgd 9/6/2003 17:55'!
becomeLikeAHolder
	(self autoLineLayout
			and: [self indicateCursor])
		ifTrue: [^ self inform: 'This view is ALREADY
behaving like a holder, which
is to say, it is set to indicate the
cursor and to have auto-line-layout.' translated].
	self behaveLikeHolder! !

!PasteUpMorph methodsFor: 'options' stamp: 'edc 2/20/2005 05:44'!
behaveLikeHolder
 
	self vResizeToFit: true; autoLineLayout: true; indicateCursor: true! !

!PasteUpMorph methodsFor: 'options' stamp: 'tk 10/30/2001 18:40'!
behaveLikeHolder: aBoolean
 	"Change the receiver's viewing properties such that they conform to what we commonly call a Holder, viz: resize-to-fit, do auto-line-layout, and indicate the 'cursor'"

	self vResizeToFit: aBoolean; autoLineLayout: aBoolean; indicateCursor: aBoolean
	! !

!PasteUpMorph methodsFor: 'options' stamp: 'sw 10/17/2000 12:04'!
behavingLikeAHolder
	"Answer whether the receiver is currently behaving like a Holder"

	^ self resizeToFit and: [self indicateCursor and: [self autoLineLayout]]! !

!PasteUpMorph methodsFor: 'options' stamp: 'sw 4/1/98 16:59'!
indicateCursor: aBoolean
	indicateCursor _ aBoolean! !

!PasteUpMorph methodsFor: 'options' stamp: 'ar 11/9/2000 12:49'!
resizeToFit
	^self vResizing == #shrinkWrap! !

!PasteUpMorph methodsFor: 'options' stamp: 'dgd 12/13/2003 19:30'!
resizeToFitString
	"Answer a string, to be used in a self-updating menu, to 
	represent whether the receiver is currently using resize-to-fit 
	or not"
	^ (self resizeToFit
		ifTrue: ['<yes>']
		ifFalse: ['<no>'])
		, 'resize to fit' translated! !