[squeak-dev] The Trunk: Multilingual-fbs.162.mcz

commits at source.squeak.org commits at source.squeak.org
Sun Jun 30 10:34:29 UTC 2013


Frank Shearar uploaded a new version of Multilingual to project The Trunk:
http://source.squeak.org/trunk/Multilingual-fbs.162.mcz

==================== Summary ====================

Name: Multilingual-fbs.162
Author: fbs
Time: 30 June 2013, 11:33:27.5 am
UUID: 29079816-610e-5748-bfb1-eacc1b4935a4
Ancestors: Multilingual-nice.161

TrueType shouldn't depend on Morphic (because Morphic should be unloadable), and since it's display related let's put it in Multilingual-Display (for the moment).

=============== Diff against Multilingual-nice.161 ===============

Item was added:
+ ----- Method: TTGlyph>>asFormWithScale:ascender:descender: (in category '*Multilingual-Display-converting') -----
+ asFormWithScale: scale ascender: ascender descender: descender
+ 	^ self
+ 		asFormWithScale: scale
+ 		ascender: ascender
+ 		descender: descender
+ 		fgColor: Color black
+ 		bgColor: Color white
+ 		depth: 8
+ 		replaceColor: true.
+ !

Item was added:
+ ----- Method: TTGlyph>>asFormWithScale:ascender:descender:fgColor:bgColor:depth: (in category '*Multilingual-Display-converting') -----
+ asFormWithScale: scale ascender: ascender descender: descender fgColor: fgColor bgColor: bgColor depth: depth
+ 
+ 	^ self
+ 		asFormWithScale: scale
+ 		ascender: ascender
+ 		descender: descender
+ 		fgColor: fgColor
+ 		bgColor: bgColor
+ 		depth: depth
+ 		replaceColor: false.
+ !

Item was added:
+ ----- Method: TTGlyph>>asFormWithScale:ascender:descender:fgColor:bgColor:depth:replaceColor: (in category '*Multilingual-Display-converting') -----
+ asFormWithScale: scale ascender: ascender descender: descender fgColor: fgColor bgColor: bgColor depth: depth replaceColor: replaceColorFlag
+ 
+ 	^ self
+ 		asFormWithScale: scale
+ 		ascender: ascender
+ 		descender: descender
+ 		fgColor: fgColor
+ 		bgColor: bgColor
+ 		depth: depth
+ 		replaceColor: replaceColorFlag
+ 		lineGlyph: nil
+ 		lingGlyphWidth: 0
+ 		emphasis: 0.!

Item was added:
+ ----- Method: TTGlyph>>asFormWithScale:ascender:descender:fgColor:bgColor:depth:replaceColor:lineGlyph:lingGlyphWidth:emphasis: (in category '*Multilingual-Display-converting') -----
+ asFormWithScale: scale ascender: ascender descender: descender fgColor: fgColor bgColor: bgColor depth: depth replaceColor: replaceColorFlag lineGlyph: lineGlyph lingGlyphWidth: lWidth emphasis: code
+ 
+ 	| form canvas newScale |
+ 	form := Form extent: (advanceWidth @ (ascender - descender) * scale) rounded depth: depth.
+ 	form fillColor: bgColor.
+ 	canvas := BalloonCanvas on: form.
+ 	canvas aaLevel: 4.
+ 	canvas transformBy: (MatrixTransform2x3 withScale: scale asPoint * (1 @ -1)).
+ 	canvas transformBy: (MatrixTransform2x3 withOffset: 0 @ ascender negated).
+ 	canvas
+ 		drawGeneralBezierShape: self contours
+ 		color: fgColor 
+ 		borderWidth: 0 
+ 		borderColor: fgColor.
+ 	((code bitAnd: 4) ~= 0 or: [(code bitAnd: 16) ~= 0]) ifTrue: [
+ 		newScale := (form width + 1) asFloat / lineGlyph calculateWidth asFloat.
+ 		canvas transformBy: (MatrixTransform2x3 withScale: (newScale / scale)@1.0).
+ 
+ 		(code bitAnd: 4) ~= 0 ifTrue: [
+ 			canvas
+ 				drawGeneralBezierShape: lineGlyph contours
+ 				color: fgColor 
+ 				borderWidth: 0 
+ 				borderColor: fgColor.
+ 		].
+ 
+ 		(code bitAnd: 16) ~= 0 ifTrue: [
+ 			canvas transformBy: (MatrixTransform2x3 withOffset: 0@(ascender // 2)).
+ 			canvas
+ 				drawGeneralBezierShape: lineGlyph contours
+ 				color: fgColor 
+ 				borderWidth: 0 
+ 				borderColor: fgColor.
+ 		].
+ 	].
+ 
+ 	replaceColorFlag ifTrue: [
+ 		form replaceColor: bgColor withColor: Color transparent.
+ 	].
+ 	^ form!



More information about the Squeak-dev mailing list