[squeak-dev] The Trunk: Morphic-eem.1044.mcz

commits at source.squeak.org commits at source.squeak.org
Wed Nov 18 20:01:18 UTC 2015


Eliot Miranda uploaded a new version of Morphic to project The Trunk:
http://source.squeak.org/trunk/Morphic-eem.1044.mcz

==================== Summary ====================

Name: Morphic-eem.1044
Author: eem
Time: 18 November 2015, 12:00:36.271 pm
UUID: 0ec2bc30-6135-4996-9005-93d4e83321df
Ancestors: Morphic-mt.1043

Fix typing of tabs in the "middle" of a line.  Only interpret the tab as an indent if the start of the selection is in a run of whitespace from the start of line.

=============== Diff against Morphic-mt.1043 ===============

Item was changed:
  ----- Method: TextEditor>>beginningOfLine: (in category 'private') -----
  beginningOfLine: position
  	"Redefined in subclasses using Paragraph support"
+ 	^ (paragraph lines at:(paragraph lineIndexOfCharacterIndex: position)) first!
- 	^ (paragraph lines at:(paragraph lineIndexFor: position)) first!

Item was changed:
  ----- Method: TextEditor>>dispatchOnKeyboardEvent: (in category 'typing support') -----
  dispatchOnKeyboardEvent: aKeyboardEvent 
  	"Carry out the action associated with this character, if any. Type-ahead is passed so some routines can flush or use it."
  	
  	| honorCommandKeys typedChar |
  	typedChar := aKeyboardEvent keyCharacter.
  	
  	"Create a new command for separating characters."
  	(Character separators includes: typedChar)
  		ifTrue: [self closeTypeIn].
  	
  	"Handle one-line input fields."
  	(typedChar == Character cr and: [morph acceptOnCR])
  		ifTrue: [^ true].
  	
  	"Clear highlight for last opened parenthesis."
  	self clearParens.
  	
  	"Handle line breaks and auto indent."
  	typedChar == Character cr ifTrue: [
  		aKeyboardEvent controlKeyPressed
  			ifTrue: [^ self normalCharacter: aKeyboardEvent].
  		aKeyboardEvent shiftPressed
  			ifTrue: [^ self lf: aKeyboardEvent].
  		aKeyboardEvent commandKeyPressed
  			ifTrue: [^ self crlf: aKeyboardEvent].
  		^ self crWithIndent: aKeyboardEvent].
  
  	"Handle indent/outdent with selected text block."
+ 	(typedChar == Character tab and: [self isInWhitespaceAtStartOfLine]) ifTrue: [
- 	(typedChar == Character tab and: [self hasSelection]) ifTrue: [
  		aKeyboardEvent shiftPressed
  			ifTrue: [self outdent: aKeyboardEvent]
  			ifFalse: [self indent: aKeyboardEvent].
  		^ true].
  
  	honorCommandKeys := Preferences cmdKeysInText.
  
  	(honorCommandKeys and: [typedChar == Character enter])
  		ifTrue: [^ self dispatchOnEnterWith: aKeyboardEvent].
  	
  	"Special keys overwrite crtl+key combinations - at least on Windows. To resolve this
  	conflict, assume that keys other than cursor keys aren't used together with Crtl."
  	((self class specialShiftCmdKeys includes: aKeyboardEvent keyValue)
  		and: [aKeyboardEvent keyValue < 27])
  			ifTrue: [^ aKeyboardEvent controlKeyPressed
  				ifTrue: [self
  							perform: (self class shiftCmdActions at: aKeyboardEvent keyValue + 1)
  							with: aKeyboardEvent]
  				ifFalse: [self
  							perform: (self class cmdActions at: aKeyboardEvent keyValue + 1)
  							with: aKeyboardEvent]].
  			
  	"backspace, and escape keys (ascii 8 and 27) are command keys"
  	((honorCommandKeys and: [aKeyboardEvent commandKeyPressed])
  		or: [self class specialShiftCmdKeys includes: aKeyboardEvent keyValue])
  			ifTrue: [ ^ aKeyboardEvent shiftPressed
  				ifTrue: [self
  							perform: (self class shiftCmdActions at: aKeyboardEvent keyValue + 1)
  							with: aKeyboardEvent]
  				ifFalse: [self
  							perform: (self class cmdActions at: aKeyboardEvent keyValue + 1)
  							with: aKeyboardEvent]].
  
  	"the control key can be used to invoke shift-cmd shortcuts"
  	(honorCommandKeys and: [ aKeyboardEvent controlKeyPressed ])
  		ifTrue: [^ self
  					perform: (self class shiftCmdActions at: aKeyboardEvent keyValue + 1)
  					with: aKeyboardEvent].
  
  	"Automatically enclose paired characters such as brackets."
  	self class autoEnclose
  		ifTrue: [((self hasSelection and: [self enclose: aKeyboardEvent])
  			or: [self autoEncloseFor: typedChar])
  				ifTrue: [^ true]].
  					
  	self normalCharacter: aKeyboardEvent.
  	^ false!

Item was added:
+ ----- Method: TextEditor>>isInWhitespaceAtStartOfLine (in category 'typing support') -----
+ isInWhitespaceAtStartOfLine
+ 	^self selectionStringFromBeginningOfLine allSatisfy: [:c| c isSeparator]!

Item was added:
+ ----- Method: TextEditor>>selectionStringFromBeginningOfLine (in category 'accessing-selection') -----
+ selectionStringFromBeginningOfLine
+ 	^paragraph string copyFrom: (self beginningOfLine: self startBlock stringIndex) to: self startBlock stringIndex!



More information about the Squeak-dev mailing list