Eliot Miranda uploaded a new version of System to project The Trunk:
http://source.squeak.org/trunk/System-eem.1237.mcz

==================== Summary ====================

Name: System-eem.1237
Author: eem
Time: 2 July 2021, 6:13:21.540315 am
UUID: 30d3cf8e-708e-4830-86da-21d106f44ba8
Ancestors: System-eem.1236

Fix MessageTally class>>#tallySends:

=============== Diff against System-eem.1236 ===============

Item was changed:
  ----- Method: MessageTally class>>tallySendsTo:inBlock:showTree: (in category 'spying') -----
  tallySendsTo: receiver inBlock: aBlock showTree: treeOption
  	"
  	MessageTally tallySends: [3.14159 printString]
  	"
  	"This method uses the simulator to count the number of calls on each method
  	invoked in evaluating aBlock. If receiver is not nil, then only sends
  	to that receiver are tallied.
  	Results are presented as leaves, sorted by frequency,
  	preceded, optionally, by the whole tree."
  	| prev tallies startTime totalTime |
  	startTime := Time millisecondClockValue.
  	tallies := MessageTally new class: aBlock receiver class method: aBlock method.
  	tallies reportOtherProcesses: true.	"Do NOT filter nodes with nil process"
  	prev := aBlock.
+ 	thisContext
- 	thisContext sender
  		runSimulated: aBlock
  		contextAtEachStep: [ :current |
  			current == prev ifFalse: [ "call or return"
  				prev sender == nil ifFalse: [ "call only"
  					(receiver == nil or: [ current receiver == receiver ])
  						ifTrue: [ tallies tally: current by: 1 ] ].
  				prev := current ] ].
  
  	totalTime := Time millisecondClockValue - startTime // 1000.0.
  	(StringHolder new contents:
  		(String streamContents:
  			[:s |
  			s nextPutAll: 'This simulation took ' , (totalTime printShowingMaxDecimalPlaces: 2)
  							, ' seconds.'; cr.
  			treeOption
  				ifTrue: [ tallies fullPrintExactOn: s ]
  				ifFalse: [ tallies leavesPrintExactOn: s ] ]))
  		openLabel: 'Spy Results'!