[squeak-dev] The Inbox: Kernel-jar.1409.mcz

commits at source.squeak.org commits at source.squeak.org
Wed May 19 17:34:01 UTC 2021


A new version of Kernel was added to project The Inbox:
http://source.squeak.org/inbox/Kernel-jar.1409.mcz

==================== Summary ====================

Name: Kernel-jar.1409
Author: jar
Time: 19 May 2021, 7:33:57.421479 pm
UUID: 6644ef0b-cdd5-3a47-9f3a-47c6639c7f82
Ancestors: Kernel-nice.1402

Replace Kernel-jar.1408 and supersede Kernel-jar.1406. This is a "final" version :)

(I noticed too late Kernel-jar.1408 uploaded incorrectly, apologies - please disregard that commit)

Clean-up, extract repeating code to a new method #complete:to:, revert an incorrect modification of #runUntilErrorOrReturnFrom from Kernel-jar.1406 and 1408, resolve MessageNotUnderstood recursion problem, update comments...

Consistent with current ProcessTest >> #testNestedUnwind semantics for completing nested halfways-through unwind blocks during termination:

x1 := x2 := x3 := nil.
p:=[
		[
			[ ] ensure: [ "halfway through completion when suspended"
				[ ] ensure: [ "halfway through completion when suspended"
					Processor activeProcess suspend. "here the process gets terminated"
					x1 := true]. 
				x2 := true]
		] ensure: [ "not started yet when suspended"
			x3 := true]
] fork.
Processor yield.
p terminate
self assert: x1 & x2 & x3.

Original discussion of the changes in #terminate: http://forum.world.st/Solving-multiple-termination-bugs-summary-amp-proposal-td5128285.html

Discussion regarding a proposal to change the current semantics: http://forum.world.st/The-semantics-of-halfway-executed-unwind-contexts-during-process-termination-td5129800.html

=============== Diff against Kernel-nice.1402 ===============

Item was changed:
  ----- Method: Context>>cannotReturn: (in category 'private-exceptions') -----
  cannotReturn: result
  
+ 	closureOrNil ifNotNil: [self cannotReturn: result to: self home sender. thisContext privRefresh].
- 	closureOrNil ifNotNil: [^ self cannotReturn: result to: self home sender].
  	Processor debugWithTitle: 'Computation has been terminated!!' translated full: false.!

Item was added:
+ ----- Method: Context>>runUnwindUntilErrorOrReturnFrom: (in category 'private') -----
+ runUnwindUntilErrorOrReturnFrom: aSender 
+ 	"ASSUMES aSender is a sender of self.  Execute self's stack until aSender returns or an unhandled exception is raised.  Return a pair containing the new top context and a possibly nil exception.  The exception is not nil if it was raised before aSender returned and it was not handled.  The exception is returned rather than openning the debugger, giving the caller the choice of how to handle it."
+ 	"Self is run by jumping directly to it (the active process abandons thisContext and executes self).  However, before jumping to self we insert an ensure block under aSender that jumps back to thisContext when evaluated.  We also insert an exception handler under aSender that jumps back to thisContext when an unhandled exception is raised.  In either case, the inserted ensure and exception handler are removed once control jumps back to thisContext."
+ 
+ 	| error ctxt here topContext |
+ 	here := thisContext.
+ 
+ 	"Insert ensure and exception handler contexts under aSender"
+ 	error := nil.
+ 	ctxt := aSender insertSender: (Context
+ 		contextOn: UnhandledError do: [:ex |
+ 			error ifNil: [
+ 				error := ex exception.
+ 				topContext := thisContext.
+ 				here jump.
+ 				ex signalerContext restart "re-signal the error when jumped back"]
+ 			ifNotNil: [ex pass]
+ 		]).
+ 	ctxt := ctxt insertSender: (Context
+ 		contextEnsure: [error ifNil: [
+ 				topContext := thisContext.
+ 				here jump]
+ 		]).
+ 	self jump.  "Control jumps to self"
+ 
+ 	"Control resumes here once above ensure block or exception handler is executed"
+ 	^ error ifNil: [
+ 		"No error was raised, remove ensure context by stepping until popped"
+ 		[ctxt isDead] whileFalse: [topContext := topContext stepToCallee].
+ 		{topContext. nil}
+ 
+ 	] ifNotNil: [
+ 		"Error was raised, remove inserted above contexts then return signaler context"
+ 		aSender terminateTo: ctxt sender.  "remove above ensure and handler contexts"
+ 		{topContext. error}
+ 	]!

Item was added:
+ ----- Method: Process>>complete:to: (in category 'private') -----
+ complete: topContext to: aContext 
+ 	"Run topContext on behalf of self on topContext's stack until aContext is popped or an unhandled 
+ 	error is raised. Return self's new top context. Note: topContext must be a stack top context.
+ 	This method is meant to be called primarily by Process>>#terminate."
+ 
+ 	| pair top error |
+ 	pair := Processor activeProcess
+ 				evaluate: [topContext runUnwindUntilErrorOrReturnFrom: aContext]
+ 				onBehalfOf: self.
+ 	top := pair first.
+ 	error := pair second.
+ 	"If an error was detected jump back to the debugged process and re-signal the error;
+ 	some errors may require a special care to prevent e.g. an infinite recursion. 
+ 	Note: BlockCannotReturn is an opportunity for further improvements."
+ 	error ifNotNil: [
+ 		error class == BlockCannotReturn ifTrue: [^top]. "do not jump back, just continue unwinding"
+ 		error class == MessageNotUnderstood ifTrue: [error initialize]. "reset reachedDefaultHandler before jump"
+ 		top jump].
+ 	^top
+ !

Item was changed:
  ----- Method: Process>>terminate (in category 'changing process state') -----
  terminate 
  	"Stop the process that the receiver represents forever.
  	 Unwind to execute pending ensure:/ifCurtailed: blocks before terminating.
  	 If the process is in the middle of a critical: critical section, release it properly."
  
+ 	| oldList top ctxt outerMost newTop unwindBlock |
+ 	"If terminating the active process, suspend it first and terminate it as a suspended process."
- 	| ctxt unwindBlock oldList outerMost |
  	self isActiveProcess ifTrue: [
- 		"If terminating the active process, suspend it first and terminate it as a suspended process."
  		[self terminate] fork.
  		^self suspend].
  
  	"Always suspend the process first so it doesn't accidentally get woken up.
+ 	N.B. If oldList is a LinkedList then the process is runnable. If it is a Semaphore/Mutex et al
+ 	then the process is blocked, and if it is nil then the process is already suspended."
- 	 N.B. If oldList is a LinkedList then the process is runnable. If it is a Semaphore/Mutex et al
- 	 then the process is blocked, and if it is nil then the process is already suspended."
  	oldList := self suspend.
+ 	suspendedContext ifNil: [^self]. "self is already terminated"
+ 	"Release any method marked with the <criticalSection> pragma.
+ 	The argument is whether the process is runnable."
+ 	self releaseCriticalSection: (oldList isNil or: [oldList class == LinkedList]).
- 	suspendedContext ifNotNil:
- 		["Release any method marked with the <criticalSection> pragma.
- 		  The argument is whether the process is runnable."
- 		 self releaseCriticalSection: (oldList isNil or: [oldList class == LinkedList]).
  
+ 	top := suspendedContext.
+ 	suspendedContext := nil. "disable this process while running its stack in active process below"
+ 	"If terminating a process halfways through an unwind, try to complete that unwind block first;
+ 	if there are multiple such nested unwind blocks, try to complete the outer-most one; the inner
+ 	blocks will be completed in the process. Halfway through blocks have already set the complete 
+ 	variable (tempAt: 2) in their defining #ensure:/#ifCurtailed contexts from nil to true."
+ 	ctxt := top.
+ 	[(ctxt := ctxt findNextUnwindContextUpTo: nil) isNil] whileFalse: [
+ 		(ctxt tempAt:2) ifNotNil: [outerMost := ctxt]].
+ 	"Let's finish the outer-most unwind context currently under evaluation (if there's one). 
+ 	Note: outerMost may in theory be the top context e.g. in case #ensure was interrupted right after 
+ 	assigning its complete := true."
+ 	outerMost ifNotNil: [newTop := self complete: top to: outerMost].
- 		"If terminating a process halfways through an unwind, try to complete that unwind block first;
- 		if there are multiple such nested unwind blocks, try to complete the outer-most one; the inner
- 		blocks will be completed in the process."
- 		ctxt := suspendedContext.
- 		[(ctxt := ctxt findNextUnwindContextUpTo: nil) isNil] whileFalse: 
- 			"Contexts under evaluation have already set their complete (tempAt: 2) to true."
- 			[(ctxt tempAt:2) ifNotNil: [outerMost := ctxt]].
- 		outerMost ifNotNil: [
- 			"This is the outer-most unwind context currently under evaluation;
- 			let's find an inner context executing outerMost's argument block (tempAt: 1)"
- 			(suspendedContext findContextSuchThat: [:ctx | 
- 				ctx closure == (outerMost tempAt: 1)]) ifNotNil: [:inner | 
- 					"Let's finish the unfinished unwind context only (i.e. up to inner) and return here"
- 					suspendedContext runUntilErrorOrReturnFrom: inner. 
- 					"Update the receiver's suspendedContext (the previous step reset its sender to nil);
- 					return, if the execution stack reached its bottom (e.g. in case of non-local returns)."
- 					(suspendedContext := outerMost sender) ifNil: [^self]]]. 
  
+ 	"By now all halfway-through unwind blocks have been completed; let's execute the ones still pending. 
+ 	Note: newTop sender points to the former outerMost sender i.e. the next unexplored context.
+ 	Note: #findNextUnwindContextUpTo: starts searching from the receiver's sender but the receiver 
+ 	itself may be an unwind context."
+ 	ctxt := newTop ifNil: [top] ifNotNil: [newTop sender].
+ 	ctxt isUnwindContext ifFalse: [ctxt := ctxt findNextUnwindContextUpTo: nil].
+ 	[ctxt isNil] whileFalse: [
+ 		(ctxt tempAt: 2) ifNil: [
+ 			ctxt tempAt: 2 put: true.
+ 			unwindBlock := ctxt tempAt: 1.
+ 			"Create a context for the unwind block and execute it on the unwind block's stack. 
+ 			Note: using #value instead of #complete:to: would lead to executing the unwind 
+ 			on the wrong stack preventing the correct execution of non-local returns."
+ 			top := unwindBlock asContextWithSender: ctxt.
+ 			self complete: top to: top].
+ 		ctxt := ctxt findNextUnwindContextUpTo: nil]
+ !
- 		"Now all unwind blocks caught halfway through have been completed; 
- 		let's execute the ones still pending. Note: #findNextUnwindContextUpTo: starts
- 		searching from the receiver's sender but the receiver itself may be an unwind context."
- 		ctxt := suspendedContext.
- 		ctxt isUnwindContext ifFalse: [ctxt := ctxt findNextUnwindContextUpTo: nil].
- 		[ctxt isNil] whileFalse: [
- 			(ctxt tempAt: 2) ifNil: [
- 				ctxt tempAt: 2 put: true.
- 				unwindBlock := ctxt tempAt: 1.
- 				"Create a context for the unwind block and execute it on the unwind block's stack. 
- 				Note: using #value instead of #runUntilErrorOrReturnFrom: would lead to executing 
- 				the unwind on the wrong stack preventing the correct execution of non-local returns."
- 				suspendedContext := unwindBlock asContextWithSender: ctxt.
- 				suspendedContext runUntilErrorOrReturnFrom: suspendedContext].
- 			ctxt := ctxt findNextUnwindContextUpTo: nil].
- 
- 		"Reset the context's pc and sender to nil for the benefit of isTerminated."
- 		suspendedContext terminate]!



More information about the Squeak-dev mailing list