Hi Marcel,


would this fix be okay for you?


And was it a deliberate decision not to add multilingual support to the system reporter or has it just been forgotten? :-)


Best,

Christoph

________________________________
Von: Squeak-dev <squeak-dev-bounces at lists.squeakfoundation.org> im Auftrag von commits at source.squeak.org <commits at source.squeak.org>
Gesendet: Donnerstag, 7. April 2022 17:57:06
An: squeak-dev at lists.squeakfoundation.org
Betreff: [squeak-dev] The Inbox: SystemReporter-ct.62.mcz

A new version of SystemReporter was added to project The Inbox:
http://source.squeak.org/inbox/SystemReporter-ct.62.mcz

==================== Summary ====================

Name: SystemReporter-ct.62
Author: ct
Time: 7 April 2022, 5:57:05.904555 pm
UUID: 9807e6b3-6613-374c-ab14-5f055f8e750d
Ancestors: SystemReporter-ct.61

Fixes "image locale" report when the new preference for compressed sources is turned on.

=============== Diff against SystemReporter-ct.61 ===============

Item was changed:
  ----- Method: SystemReporter>>reportImageLocale: (in category 'reporting') -----
  reportImageLocale: aStream

         | imageLocale platformLocale |
         imageLocale := Locale current.
         platformLocale := Locale currentPlatform.

         self header: 'Image Locale Information' on: aStream.
         aStream
                 nextPutAll: '   Locale ID: ', imageLocale localeID; cr;
                 nextPutAll: '  Translator: ', imageLocale languageTranslator; cr;
                 nextPutAll: ' Environment: ', imageLocale languageEnvironment class; nextPutAll: ' (see languages below)'; cr;
                 nextPutAll: 'Leading char: ', imageLocale leadingChar; nextPutAll: ' (ie. tag in characters)'; cr.

         aStream cr.
         self header: 'Image Default Language(s)' on: aStream.
         aStream
                 nextPutAll: (imageLocale languageEnvironment class supportedLanguageNames sorted joinSeparatedBy: ', '); cr;
                 cr; nextPutAll: '(These languages belong to the same category when Squeak uses the environment or leading char above to derive rules for language-specific text composition and display. Strings are not limited to this default. See LanguageEnvironment and its subclasses.)'; cr.

         aStream cr.
         self header: 'Data Interpretation and Conversion' on: aStream.

         aStream
+                nextPutAll: '   Source code: ',
+                        (SourceFiles
+                                "Some source files, e.g., CompressedSources, do not have a converter"
+                                detect: [:file | file respondsTo: #converter]
+                                ifFound: [:file | file converter class]
+                                ifNone: ['(none)' translated]);
+                nextPutAll: ' (ie. .sources .changes .cs .st)'; cr;
-                nextPutAll: '   Source code: ', SourceFiles anyOne converter class; nextPutAll: ' (ie. .sources .changes .cs .st)'; cr;
                 nextPutAll: ' Platform data: ',  platformLocale systemConverter class; nextPutAll: ' (aka. #systemConverter)'; cr;
                 nextPutAll: '    File names: ',  platformLocale fileNameConverter class; nextPutAll: ' (ie. no content but paths)'; cr;
                 nextPutAll: '    User input: ', platformLocale inputInterpreter class; cr;
                 nextPutAll: 'Clipboard data: ', platformLocale clipboardInterpreter class; cr.

         aStream cr.
         self header: 'Platform Locale Information' on: aStream.

         aStream
                 nextPutAll: '          Locale ID: ', platformLocale localeID; cr;
                 nextPutAll: '    Currency symbol: ', platformLocale fetchCurrencySymbol;
                         nextPutAll: (platformLocale primCurrencyNotation ifTrue: ['  (prefix)'] ifFalse: [' (postfix)']); cr;
                 nextPutAll: ('            Numbers: 1{1}234{2}56'
                         format: { platformLocale primDigitGrouping. platformLocale primDecimalSymbol}); cr;
                 nextPutAll: '        Measurement: ', (platformLocale primMeasurement ifTrue: ['metric'] ifFalse: ['imperial']); cr;
                 nextPutAll: '           Timezone: UTC', (platformLocale primTimezone >= 0 ifTrue: ['+']), (platformLocale primTimezone / 60);
                         nextPutAll: (platformLocale primDST ifTrue: [' (daylight saving time)'] ifFalse: ['']); cr;
                 nextPutAll: '        Time format: ', platformLocale primTimeFormat; cr;
                 nextPutAll: '(Short) Date format: ', platformLocale primShortDateFormat; cr;
                 nextPutAll: ' (Long) Date format: ', platformLocale primLongDateFormat; cr;
                 cr.!


-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.squeakfoundation.org/pipermail/squeak-dev/attachments/20220407/40bcda8e/attachment.html>