Marcel Taeumel uploaded a new version of MorphicTests to project The Trunk:
http://source.squeak.org/trunk/MorphicTests-mt.46.mcz
==================== Summary ====================
Name: MorphicTests-mt.46
Author: mt
Time: 6 May 2018, 3:12:17.556836 pm
UUID: da7669ef-c6b9-1e4b-a096-8ecab904367e
Ancestors: MorphicTests-mt.45
Supplement to refactoring in Morphic-mt.1427.
=============== Diff against MorphicTests-mt.45 ===============
Item was added:
+ TestCase subclass: #BorderedMorphTests
+ instanceVariableNames: ''
+ classVariableNames: ''
+ poolDictionaries: ''
+ category: 'MorphicTests-Basic'!
Item was added:
+ ----- Method: BorderedMorphTests>>test01OldInstVarRefs (in category 'tests') -----
+ test01OldInstVarRefs
+ "Only BorderedMorph should reference the (deprecated) borderWidth and borderColor isntance variables."
+
+ self
+ assert: 2
+ equals: (SystemNavigation default allAccessesTo: #borderWidth from: BorderedMorph) size.
+
+ self
+ assert: 2
+ equals: (SystemNavigation default allAccessesTo: #borderColor from: BorderedMorph) size.!
Item was added:
+ ----- Method: BorderedMorphTests>>test02ConvertColorSymbols (in category 'tests') -----
+ test02ConvertColorSymbols
+ "The use of #inset or #raised as border color should result in the use of a new border style."
+
+ | sut |
+ sut := BorderedMorph new.
+ self
+ assert: #simple equals: sut borderStyle style;
+ assert: Color black equals: sut borderStyle color.
+
+ sut borderColor: #raised.
+ self
+ assert: #raised equals: sut borderStyle style;
+ assert: Color black equals: sut borderStyle color.
+
+ "Enable color tracking."
+ sut borderColor: Color transparent.
+ self assert: sut color equals: sut borderStyle color.
+
+ sut borderColor: #inset.
+ self
+ assert: #inset equals: sut borderStyle style;
+ assert: sut color equals: sut borderStyle color.
+ !
Item was added:
+ ----- Method: BorderedMorphTests>>test03ColorTracking (in category 'tests') -----
+ test03ColorTracking
+
+ | sut c1 c2 |
+ sut := BorderedMorph new.
+ self assert: Color black equals: sut borderStyle baseColor.
+
+ sut borderInset.
+ self
+ assert: Color transparent equals: sut borderStyle baseColor;
+ assert: sut borderStyle topLeftColor ~= sut color;
+ assert: sut borderStyle bottomRightColor ~= sut color;
+ assert: sut borderStyle bottomRightColor ~= sut borderStyle topLeftColor.
+
+ c1 := sut borderStyle topLeftColor.
+ c2 := sut borderStyle bottomRightColor.
+ sut color: Color yellow.
+ self
+ assert: Color transparent equals: sut borderStyle baseColor;
+ assert: sut borderStyle topLeftColor ~= c1;
+ assert: sut borderStyle bottomRightColor ~= c2.
+
+ c1 := sut borderStyle topLeftColor.
+ c2 := sut borderStyle bottomRightColor.
+ sut borderStyle: BorderStyle raised.
+ self
+ assert: Color transparent equals: sut borderStyle baseColor;
+ assert: sut borderStyle topLeftColor = c2;
+ assert: sut borderStyle bottomRightColor = c1.!
Marcel Taeumel uploaded a new version of Graphics to project The Trunk:
http://source.squeak.org/trunk/Graphics-mt.398.mcz
==================== Summary ====================
Name: Graphics-mt.398
Author: mt
Time: 6 May 2018, 3:08:37.011836 pm
UUID: 73c0a26a-9209-cb42-90b7-b679bb5b467d
Ancestors: Graphics-mt.397
Supplement to refactoring in Morphic-mt.1427.
=============== Diff against Graphics-mt.397 ===============
Item was added:
+ ----- Method: Form class>>dotOfSize:color: (in category 'examples') -----
+ dotOfSize: diameter color: color
+
+ | form |
+ form := self extent: diameter asPoint depth: Display depth.
+ form getCanvas fillOval: form boundingBox color: color.
+ ^form!
Marcel Taeumel uploaded a new version of 60Deprecated to project The Trunk:
http://source.squeak.org/trunk/60Deprecated-mt.18.mcz
==================== Summary ====================
Name: 60Deprecated-mt.18
Author: mt
Time: 6 May 2018, 3:04:54.850836 pm
UUID: c3fb6f9b-652f-c640-a2d9-61e690ffe944
Ancestors: 60Deprecated-pre.17
Supplement to refactoring in Morphic-mt.1427.
=============== Diff against 60Deprecated-pre.17 ===============
Item was added:
+ ----- Method: BorderStyle>>colorsAtCorners (in category '*60Deprecated-accessing') -----
+ colorsAtCorners
+
+ self deprecated: 'See #topLeftColor and #bottomRightColor.'.
+ ^Array new: 4 withAll: self color!
Item was added:
+ ----- Method: BorderStyle>>dotOfSize:forDirection: (in category '*60Deprecated-accessing') -----
+ dotOfSize: diameter forDirection: aDirection
+
+ self deprecated: 'See Form for such convenience functions.'.
+ ^ Form dotOfSize: diameter color: self color!
Item was added:
+ ----- Method: BorderStyle>>widthForRounding (in category '*60Deprecated-accessing') -----
+ widthForRounding
+
+ self deprecated: 'See BalloonCanvas for drawing rounded corners.'.
+ ^self width!
Item was added:
+ ----- Method: BorderedMorph>>doesBevels (in category '*60Deprecated-accessing') -----
+ doesBevels
+ "To return true means that this object can show bevelled borders, and
+ therefore can accept, eg, #raised or #inset as valid borderColors.
+ Must be overridden by subclasses that do not support bevelled borders."
+
+ self deprecated: 'Use border styles such as InsetBorder or RaisedBorder.'.
+ ^ false!
Item was added:
+ ----- Method: ComplexBorder>>widthForRounding (in category '*60Deprecated-accessing') -----
+ widthForRounding
+
+ self deprecated: 'See BalloonCanvas for drawing rounded corners.'.
+ ^0!
Item was added:
+ ----- Method: EllipseMorph>>doesBevels (in category '*60Deprecated-accessing') -----
+ doesBevels
+ self deprecated: 'Use border styles such as InsetBorder or RaisedBorder.'.
+ ^ false!
Item was added:
+ ----- Method: InsetBorder>>colorsAtCorners (in category '*60Deprecated-accessing') -----
+ colorsAtCorners
+
+ | c c14 c23 |
+ self deprecated: 'See #topLeftColor and #bottomRightColor.'.
+
+ c := self color.
+ c14 := c lighter. c23 := c darker.
+ ^Array with: c23 with: c14 with: c14 with: c23.!
Item was added:
+ ----- Method: Morph>>doesBevels (in category '*60Deprecated-accessing') -----
+ doesBevels
+ "To return true means that this object can show bevelled borders, and
+ therefore can accept, eg, #raised or #inset as valid borderColors.
+ Must be overridden by subclasses that do not support bevelled borders."
+
+ self deprecated: 'Use border styles such as InsetBorder or RaisedBorder.'.
+ ^ false!
Item was added:
+ ----- Method: RaisedBorder>>colorsAtCorners (in category '*60Deprecated-accessing') -----
+ colorsAtCorners
+
+ | c c14 c23 |
+ self deprecated: 'See #topLeftColor and #bottomRightColor.'.
+ c := self color.
+ c14 := c lighter. c23 := c darker.
+ ^Array with: c14 with: c23 with: c23 with: c14!
Item was added:
+ ----- Method: TTSampleFontMorph>>doesBevels (in category '*60Deprecated-accessing') -----
+ doesBevels
+ self deprecated: 'Use border styles such as InsetBorder or RaisedBorder.'.
+ ^ false!