[FIX] ColorForm>>storeOn 2
Michael Rueger
Michael.Rueger.-ND at disney.com
Wed Jul 21 19:06:07 UTC 1999
.... and the sources...
Sorry
Michael
--
"To improve is to change, to be perfect is to change often."
Winston Churchill
+------------------------------------------------------------+
| Michael Rueger |
| Phone: ++1 (818) 623 3283 Fax: ++1 (818) 623 3559 |
+--------Michael.Rueger.-ND at online.disney.com----------------+
'From Squeak 2.4c of May 10, 1999 on 21 July 1999 at 11:56:39 am'!
!Color methodsFor: 'printing' stamp: 'mir 7/21/1999 11:41'!
storeArrayOn: aStream
aStream nextPutAll: '#('.
self storeArrayValuesOn: aStream.
aStream nextPutAll: ') '
! !
!Color methodsFor: 'printing' stamp: 'mir 7/21/1999 11:41'!
storeArrayValuesOn: aStream
(self red roundTo: 0.001) storeOn: aStream.
aStream space.
(self green roundTo: 0.001) storeOn: aStream.
aStream space.
(self blue roundTo: 0.001) storeOn: aStream.
! !
!Color class methodsFor: 'instance creation' stamp: 'mir 7/21/1999 11:54'!
fromArray: colorDef
colorDef size == 3
ifTrue: [^self r: (colorDef at: 1) g: (colorDef at: 2) b: (colorDef at: 3)].
colorDef size == 0
ifTrue: [^Color transparent].
colorDef size == 4
ifTrue: [^(TranslucentColor r: (colorDef at: 1) g: (colorDef at: 2) b: (colorDef at: 3)) alpha: (colorDef at: 4)].
self error: 'Undefined color definition'! !
!ColorForm methodsFor: 'accessing' stamp: 'mir 7/21/1999 11:51'!
colorsFromArray: colorArray
| colorList |
colorList _ colorArray collect: [:colorDef |
Color fromArray: colorDef].
self colors: colorList! !
!ColorForm methodsFor: 'fileIn/Out' stamp: 'mir 7/21/1999 11:44'!
storeOn: aStream
super storeOn: aStream.
aStream
cr; tab;
nextPutAll: 'colorsFromArray: #('.
self colors do: [:color |
color storeArrayOn: aStream].
aStream nextPutAll: ' )'.! !
!TranslucentColor methodsFor: 'printing' stamp: 'mir 7/21/1999 11:43'!
storeArrayValuesOn: aStream
self isTransparent ifTrue: [
^ aStream space].
super storeArrayValuesOn: aStream.
aStream space.
(self alpha roundTo: 0.001) storeOn: aStream.
! !
More information about the Squeak-dev
mailing list
|