Levente Uzonyi uploaded a new version of Kernel to project The Trunk:
http://source.squeak.org/trunk/Kernel-ul.406.mcz

==================== Summary ====================

Name: Kernel-ul.406
Author: ul
Time: 23 February 2010, 4:32:14.835 pm
UUID: c35323f5-b49d-6a45-8b3f-aab75d51c382
Ancestors: Kernel-nice.405

- an implementation of the #cull: protocol

=============== Diff against Kernel-nice.405 ===============

Item was added:
+ ----- Method: BlockClosure>>cull:cull: (in category 'evaluating') -----
+ cull: firstArg cull: secondArg
+ 	"Activate the receiver, with two or less arguments."
+ 	
+ 	numArgs >= 2 ifTrue: [ ^self value: firstArg value: secondArg ].	
+ 	numArgs = 1 ifTrue: [ ^self value: firstArg ].
+ 	^self value!

Item was added:
+ ----- Method: BlockClosure>>cull:cull:cull:cull: (in category 'evaluating') -----
+ cull: firstArg cull: secondArg cull: thirdArg cull: fourthArg
+ 	"Activate the receiver, with four or less arguments."
+ 	
+ 	numArgs >= 3 ifTrue: [
+ 		numArgs >= 4 ifTrue: [
+ 			^self value: firstArg value: secondArg value: thirdArg value: fourthArg ].
+ 		^self value: firstArg value: secondArg value: thirdArg ].
+ 	numArgs = 2 ifTrue: [ ^self value: firstArg value: secondArg ].	
+ 	numArgs = 1 ifTrue: [ ^self value: firstArg ].
+ 	^self value!

Item was added:
+ ----- Method: BlockClosure>>cull:cull:cull: (in category 'evaluating') -----
+ cull: firstArg cull: secondArg cull: thirdArg
+ 	"Activate the receiver, with three or less arguments."
+ 	
+ 	numArgs >= 2 ifTrue: [ 
+ 		numArgs >= 3 ifTrue: [ ^self value: firstArg value: secondArg value: thirdArg ].
+ 		^self value: firstArg value: secondArg ].
+ 	numArgs = 1 ifTrue: [ ^self value: firstArg ].
+ 	^self value!

Item was added:
+ ----- Method: BlockClosure>>cull: (in category 'evaluating') -----
+ cull: firstArg
+ 	"Activate the receiver, with one or zero arguments."
+ 	
+ 	numArgs >= 1 ifTrue: [ ^self value: firstArg ].
+ 	^self value!