A new version of ToolsTests was added to project The Inbox:
http://source.squeak.org/inbox/ToolsTests-jr.117.mcz

==================== Summary ====================

Name: ToolsTests-jr.117
Author: jr
Time: 21 August 2022, 7:20:26.542081 pm
UUID: da55a869-d21e-a243-8423-d264308aaed8
Ancestors: ToolsTests-jar.116

Tests for MessageNavigation

=============== Diff against ToolsTests-jar.116 ===============

Item was added:
+ TestCase subclass: #MessageNavigationTest
+ 	instanceVariableNames: 'navigation'
+ 	classVariableNames: ''
+ 	poolDictionaries: ''
+ 	category: 'ToolsTests-Browser'!

Item was added:
+ ----- Method: MessageNavigationTest>>setUp (in category 'tests') -----
+ setUp
+ 	navigation := MessageNavigation new.!

Item was added:
+ ----- Method: MessageNavigationTest>>testBeforeNavigatedToFirst (in category 'tests') -----
+ testBeforeNavigatedToFirst
+ 	self assert: nil equals: navigation goBack.
+ 	self assert: nil equals: navigation goForward.!

Item was added:
+ ----- Method: MessageNavigationTest>>testCanGoBackAndForwardMultipleTimes (in category 'tests') -----
+ testCanGoBackAndForwardMultipleTimes
+ 	self testCanGoBackMultipleTimes.
+ 	self assert: #b equals: navigation goForward.
+ 	self assert: #c equals: navigation goForward.
+ 	self assert: #b equals: navigation goBack.
+ 	self assert: #a equals: navigation goBack.!

Item was added:
+ ----- Method: MessageNavigationTest>>testCanGoBackMultipleTimes (in category 'tests') -----
+ testCanGoBackMultipleTimes
+ 	#(a b c) do: [:each | navigation current: each].
+ 	self assert: #b equals: navigation goBack.
+ 	self assert: #a equals: navigation goBack.!

Item was added:
+ ----- Method: MessageNavigationTest>>testDiscardsForwardHistoryIfUsersTakeAnotherPath (in category 'tests') -----
+ testDiscardsForwardHistoryIfUsersTakeAnotherPath
+ 	#(a b c) do: [:each | navigation current: each].
+ 	navigation goBack. "to b"
+ 	navigation current: #d.
+ 	self assert: #d equals: navigation goForward.!

Item was added:
+ ----- Method: MessageNavigationTest>>testDoesNotLoseForwardHistoryIfNextIsSelectedAgain (in category 'tests') -----
+ testDoesNotLoseForwardHistoryIfNextIsSelectedAgain
+ 	#(a b c) do: [:each | navigation current: each].
+ 	navigation goBack. "to b"
+ 	navigation goBack. "to a"
+ 	navigation current: #b.
+ 	self assert: #c equals: navigation goForward.!

Item was added:
+ ----- Method: MessageNavigationTest>>testDoesNotLoseForwardHistoryIfPreviousIsSelectedAgain (in category 'tests') -----
+ testDoesNotLoseForwardHistoryIfPreviousIsSelectedAgain
+ 	#(a b c) do: [:each | navigation current: each].
+ 	navigation goBack. "to b"
+ 	navigation current: #a.
+ 	self assert: #b equals: navigation goForward.
+ 	self assert: #c equals: navigation goForward.!

Item was added:
+ ----- Method: MessageNavigationTest>>testGoBackStaysIfHistoryIsEmpty (in category 'tests') -----
+ testGoBackStaysIfHistoryIsEmpty
+ 	navigation current: #a.
+ 	self assert: #a equals: navigation goBack.!

Item was added:
+ ----- Method: MessageNavigationTest>>testGoForwardStaysIfHistoryIsEmpty (in category 'tests') -----
+ testGoForwardStaysIfHistoryIsEmpty
+ 	navigation current: #a.
+ 	self assert: #a equals: navigation goForward.!